1 GO TO 9045
10 LET FASE=0:LET SCORE=0:LET VIDAS=3:OVER 1:BORDER 0:PAPER 7:INK 0:CLS :GO TO 5516
97 :
98 REM *** CICLO PRINCIPAL **
99 :
100 LET TIEMPO=TIEMPO-.5:PLOT OVER 0;INVERSE 1;PAPER 0;INK 8;TIEMPO,165:DRAW OVER 0;INVERSE 1;PAPER 0;INK 8;0,-3:IF TIEMPO=70 THEN GO TO 5000
110 FOR N=1 TO 5:IF A(N)=-1 THEN GO TO 290
111 IF INKEY$ <>"" THEN GO SUB 300
112 LET F$=("abcdefgh" AND E(N)=-1)+("efghabcd" AND E(N)=1)+("ijklmnop" AND E(N)=0)+("mnopijkl" AND E(N)=2)
113 :
114 REM BICHO EN AGUJERO
115 IF A(N)<>1 THEN GO TO 120
116 LET T(N)=T(N)+C(N):IF T(N)<>36 THEN GO TO 270
117 LET T(N)=0:LET A(N)=0:LET E(N)=A(N)+B(N):LET W(N)=0:PRINT OVER 0; AT Y(N),X(N);INK 1;"qq"; AT Y(N)+1,X(N);INK 0;"  ":LET Y(N)=Y(N)-2
118 LET F$=("abcd" AND E(N)=-1)+("efgh" AND E(N)=1):GO TO 270
130 FOR R=1 TO 5:IF Y(R)=Y THEN IF X(R)=X OR X(R)+1=X THEN GO TO 5030
140 NEXT R
149 REM  BICHO LIBRE (MOV.)
150 IF A(N)<>0 THEN GO TO 220
160 IF SCREEN$ (Y(N)+2,X(N))=" " THEN IF SCREEN$ (Y(N)+2,X(N)+1)=" " THEN LET Y(N)=Y(N)+2:LET A(N)=1:LET W(N)=0:LET V(N)=0:LET F$=("ijklefgh" AND E(N)=-1)+("mnopabcd" AND E(N)=1):GO TO 270
170 IF Y(N)=Y AND (Y(N)+1)/4=INT ((Y(N)+1)/4) THEN LET V(N)=0:LET W(N)=(X(N)<X)-(X(N)>X):GO TO 212
180 IF Y(N)<Y THEN IF ATTR (Y(N)+2,X(N))=56 AND ATTR (Y(N)+2,X(N)+1)=56 THEN LET W(N)=0:LET V(N)=1:GO TO 270
190 IF Y(N)>Y THEN IF ATTR (Y(N)-2,X(N))=56 AND ATTR (Y(N)-2,X(N)+1)=56 THEN IF (SCREEN$ (Y(N)-2,X(N))<>" " AND SCREEN$ (Y(N)-2,X(N)+1)<>" ") THEN LET W(N)=0:LET V(N)=-1:GO TO 270
200 IF (Y(N)+1)/4=INT ((Y(N)+1)/4) AND W(N)=0 THEN LET W(N)=(X(N)<X)-(X(N)>X):LET V(N)=0
212 IF W(N)=1 AND ATTR (Y(N),X(N)+2)<>56 THEN LET W(N)=-1
214 IF W(N)=-1 THEN IF ATTR (Y(N),X(N)-1)<>56 THEN LET W(N)=1
215 IF X(N)<1 OR X(N)>29 THEN LET W(N)=-W(N)
218 GO TO 270
219 REM   BICHO CAYENDO  
220 IF A(N)<=1 THEN GO TO 270
225 IF (Y(N)+1)/4<>INT ((Y(N)+1)/4) THEN GO TO 235
230 IF SCREEN$ (Y(N)+2,X(N))=" " AND SCREEN$ (Y(N)+2,X(N)+1)=" " THEN GO TO 235
231 GO TO 240
235 LET A(N)=A(N)+1:LET B(N)=-B(N):LET E(N)=(2 AND E(N)=0):LET Y(N)=Y(N)+1:IF (Y(N)-3)/4=INT ((Y(N)-3)/4) THEN PRINT OVER 0;INK 1; AT Y(N)-2,X(N);"qq"
236 GO TO 280
240 IF A(N)<2*C(N) THEN LET A(N)=0:LET W(N)=(X(N)<X)-(X(N)>X):LET F$=("abcdmnop" AND E(N)=0)+("efghijkl" AND E(N)=2):GO TO 270
260 LET A(N)=-1:PRINT INK 0;PAPER 7; AT Y(N),X(N);F$(5 TO 6); AT Y(N)+1,X(N);F$(7 TO ); AT Y(N),X(N);"żż"; AT Y(N)+1,X(N);"żż":FOR K=30 TO -30 STEP -5:BEEP .01,K:NEXT K:PRINT  AT Y(N),X(N);"żż"; AT Y(N)+1,X(N);"żż":LET X(N)=-1:LET Y(N)=-1:LET SCORE=SCORE+C(N)*40+FASE*20:PRINT #0; AT 1,13-LEN (STR$ SCORE);BRIGHT 1;SCORE;
265 LET BICHO=BICHO-1:IF BICHO>0 THEN GO TO 290
266 OVER 0:FOR N=TIEMPO TO 70 STEP -1:PRINT  AT Y-1,X;"A"; AT Y,X;"B"; AT Y+1,X;" ":BEEP .01,50:PLOT OVER 0;PAPER 0;INK 8;INVERSE 1;N,165:DRAW OVER 0;PAPER 0;INK 8;INVERSE 1;0,-3:LET SCORE=SCORE+FASE*10:PRINT #0; AT 1,13-LEN (STR$ SCORE);BRIGHT 1;SCORE;:PRINT  AT Y-1,X;" "; AT Y,X;"A"; AT Y+1,X;"B":BEEP .01,30
267 NEXT N:OVER 1:IF FASE<>21 THEN GO TO 5500
268 GO TO 9200
269 REM   ACTUALIZAR POSICION 
270 LET B(N)=-B(N):LET E(N)=A(N)+B(N):LET X(N)=X(N)+W(N):LET Y(N)=Y(N)+V(N)
279 REM      DIBUJAR   
280 IF LEN F$=8 THEN PRINT INK 9; AT I(N),H(N);F$(5 TO 6); AT I(N)+1,H(N);F$(7 TO )
285 PRINT  AT Y(N),X(N);INK C(N);F$( TO 2); AT Y(N)+1,X(N);F$(3 TO 4):LET H(N)=X(N):LET I(N)=Y(N)
289 REM    VOLVER A REPETIR  
290 NEXT N:GO TO 100
297 :
298 REM    MOVIMIENTO HOMBRE  
299 :
320 INK 8:BRIGHT 8
330 IF INKEY$ ="P" AND SENTIDO=1 THEN IF X<30 THEN LET X=X+1:PRINT  AT Y,X-1;"CG"; AT Y+1,X-1;"DH":BEEP .01,0:PRINT  AT Y,X;"G"; AT Y+1,X;"H"; AT Y,X;"C"; AT Y+1,X;"D"
340 IF INKEY$ ="P" AND SENTIDO=-1 THEN LET SENTIDO=1:PRINT  AT Y,X;"A"; AT Y+1,X;"B"; AT Y,X;"C"; AT Y+1,X;"D":RETURN 
350 IF INKEY$ ="O" AND SENTIDO=-1 THEN IF X>1 THEN LET X=X-1:PRINT  AT Y,X;"EA"; AT Y+1,X;"FB":BEEP .01,0:PRINT  AT Y,X;"E"; AT Y+1,X;"F"; AT Y,X;"A"; AT Y+1,X;"B"
360 IF INKEY$ ="O" AND SENTIDO=1 THEN LET SENTIDO=-1:PRINT  AT Y,X;"C"; AT Y+1,X;"D"; AT Y,X;"A"; AT Y+1,X;"B":RETURN 
370 IF SENTIDO=-1 THEN LET A$="A":LET B$="B":LET X$="QR":LET Y$=" L":LET V$="IJ":LET W$="KL"
380 IF SENTIDO=1 THEN LET A$="C":LET B$="D":LET X$="ST":LET Y$="O ":LET V$="MN":LET W$="OP"
390 IF INKEY$ ="Q" AND ATTR (Y-2,X)=56 THEN IF Y<>3 THEN PRINT  AT Y,X;A$; AT Y+1,X;B$:LET Y=Y-1:PRINT  AT Y,X;A$; AT Y+1,X;B$
400 IF INKEY$ ="A" AND ATTR (Y+2,X)=56 THEN PRINT  AT Y,X;A$; AT Y+1,X;B$:LET Y=Y+1:PRINT  AT Y,X;A$; AT Y+1,X;B$
410 IF SCREEN$ (Y+2,X)=" " THEN PRINT  AT Y,X;A$; AT Y+1,X;B$:LET Y=Y+1:PRINT  AT Y,X;A$; AT Y+1,X;B$:GO TO 410
420 IF INKEY$ <>"Z" AND INKEY$ <>"M" THEN RETURN 
430 LET S$=SCREEN$ (Y+2,X+SENTIDO)
440 LET O$=("r" AND S$="q")+("s" AND S$="r")+(" " AND S$="s")
450 LET C$=("q" AND S$="r")+("r" AND S$="s")+("s" AND S$=" ")
460 IF INKEY$ ="M" AND Y<18 AND SENTIDO=1 THEN IF (ATTR (Y+2,X+1)=57 AND SCREEN$ (Y,X+1)=" ") THEN LET F$=O$:LET V=X:GO SUB 510
470 IF INKEY$ ="M" AND Y<18 AND SENTIDO=-1 THEN IF (ATTR (Y+2,X-1)=57 AND SCREEN$ (Y,X-1)=" ") THEN LET F$=O$:LET V=X-1:GO SUB 510
475 IF INKEY$ <>"Z" THEN RETURN 
480 IF INKEY$ ="Z" AND SENTIDO=1 THEN IF ATTR (Y+2,X+1)<>56 THEN LET F$=C$:LET V=X:GO SUB 510
490 IF INKEY$ ="Z" AND SENTIDO=-1 THEN IF ATTR (Y+2,X-1)<>56 THEN LET F$=C$:LET V=X:GO SUB 510
495 FOR J=1 TO 5:IF Y(J)=Y+2 THEN IF (X(J)=X AND SENTIDO=1) OR (X(J)+1=X AND SENTIDO=-1) THEN LET V=X:GO SUB 510:LET A(J)=2:RETURN 
496 NEXT J
500 RETURN 
510 PRINT  AT Y,X;A$; AT Y+1,X;B$; AT Y,V;X$; AT Y+1,V;Y$:BEEP .01,30:PRINT  AT Y,V;X$; AT Y+1,V;Y$; AT Y,V;V$; AT Y+1,V;W$; AT Y+2,X+SENTIDO;OVER 0;INK 1;F$:BEEP .01,0:PRINT  AT Y,V;V$; AT Y+1,V;W$; AT Y,X;A$; AT Y+1,X;B$:RETURN 
4999 REM PIERDE UNA VIDA
5000 REM POR TIEMPO
5010 OVER 0:PRINT  AT 1,1;PAPER 0;INK 7;FLASH 1;BRIGHT 1;"TIEMPO":FOR N=1 TO 15:PRINT  AT Y,X;"E"; AT Y+1,X;"F":BEEP .1,40:PRINT  AT Y,X;"G"; AT Y+1,X;"H":BEEP .1,50:NEXT N
5020 PRINT  AT 1,1;PAPER 0;INK 7;BRIGHT 1;"TIEMPO":LET A=X*8:LET B=176-Y*8:FOR N=B TO B-16 STEP -1:BEEP .001,INT (RND *40+20):PLOT OVER 0;INVERSE 1;A,N:DRAW OVER 0;INVERSE 1;8,0:NEXT N:PRINT  AT Y,X;" "; AT Y+1,X;" ":GO TO 5040
5029 REM POR BICHO
5030 IF SENTIDO=1 THEN PRINT  AT Y,X;"C"; AT Y+1,X;"D";
5035 IF SENTIDO=-1 THEN PRINT  AT Y,X;"A"; AT Y+1,X;"B";
5036 FOR N=1 TO 5:FOR K=60 TO 30 STEP -5:BEEP .005,0:BEEP .005,K:NEXT K:NEXT N
5039 REM PROTOCOLO
5040 OVER 0:LET VIDAS=VIDAS-1:PRINT  AT 0,29;PAPER 0;BRIGHT 1;INK 7;VIDAS:IF VIDAS>0 THEN GO TO 5050:LET HIGH=(SCORE AND HIGH<SCORE)+(HIGH AND HIGH>=SCORE):FOR N=2 TO 21:PRINT  AT N,0;FLASH 1;PAPER INT (RND *5+3);INK 0;"      G A M E    O V E R        ";:BEEP .1,N:BEEP .1,40-N:NEXT N:PAUSE 20:GO TO 9050
5041 LET HIGH=(SCORE AND HIGH<SCORE)+(HIGH AND HIGH>=SCORE):FOR N=2 TO 21:PRINT  AT N,0;FLASH 1;PAPER INT (RND *5+3);INK 0;"      G A M E    O V E R        ";:BEEP .1,N:BEEP .1,40-N:NEXT N:PAUSE 20
5042 PAPER 0:INK 7:BRIGHT 1:CLS :PRINT  AT 5,5;"HAS CONSEGUIDO UN ";INT (((SCORE*100)/455700)+.5);"% DE"; AT 7,6;"LA PUNTUACION MAXIMA":PAUSE 100:GO TO 9050
5050 FOR N=TIEMPO TO 250:LET G=(2 AND N<=111)+(4 AND N>=112):PLOT INK G;N,165:DRAW INK G;0,-3:NEXT N:LET Y=19:LET X=15:LET XA=X:LET YA=Y:LET SENTIDO=1:LET TIEMPO=251
5060 IF SCREEN$ (Y,X)<>" " THEN LET X=X+3:GO TO 5060
5070 OVER 1:PRINT  AT Y,X;"C"; AT Y+1,X;"D":GO TO 100
5500 REM PROTOCOLO ENTRE FASE
5510 BRIGHT 1:PAPER 0:INK 7:BORDER 0:CLS :OVER 0:CLS 
5511 LET TOP=1800*FASE:FOR N=1 TO LEN K$:LET TOP=TOP+VAL (K$(N))*40+FASE*20:NEXT N
5515 PRINT  AT 5,7;"HAS ACABADO LA FASE ";FASE; AT 7,3;"CON UN ";INT (((SCORE*100)/TOP)+.5);"% DE LA PUNTUACION"; AT 9,7;"MAXIMA DE DICHA FASE":PAUSE 50:BEEP .5,0
5516 BRIGHT 1:PAPER 0:INK 7:BORDER 0:CLS :OVER 0:CLS 
5520 CLS :PRINT  AT 3,13;INK 6;FLASH 1;"FASE ";FASE+1:RESTORE 8009+FASE+1:READ A,B,C,D,E:LET K$=STR$ A+STR$ B+STR$ C+STR$ D+STR$ E
5530 LET S=0:LET Y=8:LET SS=0:FOR N=1 TO LEN K$:IF STR$ S<>K$(N) THEN LET S=VAL K$(N):LET SS=SS+1:LET Y=Y+3:PRINT  AT Y-1,5;INK S;"ab"; AT Y,5;"cd";INK 0;" ........ ";S*40+(FASE+1)*20;" PUNTOS":BEEP .1,50
5535 NEXT N
5540 LET A=7:LET B=26:FOR U=1 TO SS:LET C=Y-3*(U-1):LET D=Y-3*(U-1):GO SUB 9900:NEXT U:PAUSE 100
5550 PAPER 7:BRIGHT 0:INK 0:OVER 1:CLS 
5999 REM     MANEJO FASES  
6000 CLS :DIM X(5):DIM Y(5):DIM H(5):DIM I(5):DIM A(5):DIM C(5):DIM E(5):DIM B(5):DIM W(5):DIM V(5):DIM T(5)
6005 LET Y=19:LET X=15:LET XA=X:LET YA=Y:LET SENTIDO=1:LET TIEMPO=251:LET BICHO=5
6007 PRINT #0;BRIGHT 1;" SCORE:000000";TAB 16;"HI-SCORE:000000"; AT 1,13-LEN (STR$ SCORE);BRIGHT 1;SCORE; AT 1,(31-LEN STR$ (HIGH));BRIGHT 1;HIGH;
6008 PRINT PAPER 0;INK 7;BRIGHT 1; AT 0,0;" FASE: 00             VIDAS: ";VIDAS;"   TIEMPO:                        "; AT 0,9-LEN (STR$ (FASE+1));OVER 0;PAPER 0;INK 7;BRIGHT 1;FASE+1
6009 FOR N=70 TO 111:PLOT INK 2;N,165:DRAW INK 2;0,-3:NEXT N:FOR N=112 TO 250:PLOT INK 4;N,165:DRAW INK 4;0,-3:NEXT N
6010 LET FASE=FASE+1:FOR N=5 TO 21 STEP 4:PRINT  AT N,0;INK 1;PAPER 7;OVER 0;"qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq";:NEXT N
6015 PRINT INK 0;PAPER 7; AT Y,X;"C"; AT Y+1,X;"D":BEEP .5,55
6020 GO SUB 7000:FOR N=1 TO 5:LET X(N)=INT (RND *20+5):LET X(5)=INT (RND *7+3):LET H(N)=X(N):LET Y(N)=N*4-1:LET I(N)=Y(N)
6030 LET A(N)=0:LET B(N)=INT (RND *2):LET B(N)=B(N)-(B(N)=0):LET E(N)=A(N)+B(N):LET T(N)=0:LET W(N)=(X>X(N))-(X<X(N)):LET W(N)=W(N)+(W(N)=0):LET V(N)=0
6040 IF B(N)=-1 THEN PRINT INK C(N); AT Y(N),X(N);"ef"; AT Y(N)+1,X(N);"gh":BEEP .1,INT (RND *10+35):GO TO 6060
6050 IF B(N)=1 THEN PRINT INK C(N); AT Y(N),X(N);"ab"; AT Y(N)+1,X(N);"cd":BEEP .1,INT (RND *10+35)
6060 NEXT N
6990 GO TO 100
6999 REM     FASES  
7000 RESTORE 8009+FASE:FOR N=5 TO 1 STEP -1:READ C(N):NEXT N
7010 LET FAS=FASE-(7 AND FASE>7)-(7 AND FASE>14)
7020 RESTORE 7999+FAS:READ A:FOR N=1 TO A:READ L,LL,LLL:FOR K=LLL TO LLL+(L*4)-1:PRINT INK 0;OVER 0;PAPER 7; AT K,LL;"tu":NEXT K:NEXT N:RETURN 
7999 REM  FASE I
8000 DATA 5,2,5,5,1,8,5,1,17,13,3,26,9,1,5,17
8001 DATA 5,3,3,5,1,19,5,2,27,5,2,10,13,1,27,17
8002 DATA 6,2,5,5,2,11,9,2,26,5,1,22,13,1,5,17,1,26,17
8003 DATA 5,4,3,5,1,24,5,1,18,9,1,10,13,1,18,17
8004 DATA 6,1,3,5,2,9,5,3,14,5,1,26,9,2,5,13,1,22,17
8005 DATA 5,4,5,5,3,10,5,2,15,5,3,20,5,4,25,5
8006 DATA 6,2,3,9,1,10,5,2,10,13,2,23,5,1,19,17,2,26,13
8007 REM 
8008 REM 
8010 DATA 2,2,2,2,2
8011 DATA 2,2,2,2,4
8012 DATA 2,2,2,4,4
8013 DATA 2,2,2,2,6
8014 DATA 2,2,2,4,6
8015 DATA 2,2,4,4,4
8016 DATA 2,2,4,4,6
8017 DATA 2,2,2,6,6
8018 DATA 2,4,4,4,4
8019 DATA 2,2,4,6,6
8020 DATA 2,4,4,4,6
8021 DATA 2,4,4,6,6
8022 DATA 2,2,6,6,6
8023 DATA 4,4,4,4,4
8024 DATA 4,4,4,4,6
8025 DATA 4,4,4,6,6
8026 DATA 2,4,6,6,6
8027 DATA 4,4,6,6,6
8028 DATA 2,6,6,6,6
8029 DATA 4,6,6,6,6
8030 DATA 6,6,6,6,6
8999 REM INICIACION
9000 CLEAR58879:PAPER 0:INK 0:BRIGHT 1:BORDER 0:CLS 
9005 RESTORE 9010:FOR N=60000 TO 60011:READ A:POKE N,A:NEXT N
9010 DATA 33,0,60,17,0,230,1,0,4,237,176,201
9020 RANDOMIZE USR 60000
9030 LOAD ""CODE 59656:LOAD ""CODE USR "A"
9031 INK 7
9035 CLS :PRINT  AT 8,8;INK 0;"PARA LA CINTA!!!":LET A=8:LET B=23:LET C=8:LET D=8:GO SUB 9900:BEEP .5,0:PAUSE 30:BEEP .5,0
9040 POKE 23658,8:POKE 23606,0:POKE 23607,230
9041 CLS :LET A$="    qqqqq qqqqq q   q q qqqqq       q   q q   q qq  q q q           q   q q   q q q q q q           qqqqq qqqqq q q q q q           q     q   q q  qq q q           q     q   q q   q q qqqqq   "
9042 PRINT  AT 8,0;PAPER 0;INK 0;A$:LET A=4:LET B=28:LET C=8:LET D=13:GO SUB 9900:PRINT INK 0; AT 18,0;"PROGRAMADO POR......EDUARDO MENA":LET A=0:LET B=19:LET C=18:LET D=18:PAUSE 40:GO SUB 9900:PAUSE 40:LET A=20:LET B=31:GO SUB 9900
9043 PRINT  AT 0,0;INK 0;"qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq PULSA UNA TECLA PARA EMPEZAR qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq":LET A=0:LET B=31:LET C=0:LET D=2:GO SUB 9900:PAUSE 0:BRIGHT 0
9045 LET HIGH=0
9050 BRIGHT 0:OVER 1:POKE 23658,8:PAPER 6:INK 0:BORDER 6:CLS 
9055 PRINT  AT 0,10;"UUUUUUUUUUUUU"; AT 1,10;"U           U"; AT 2,10;"U           U"; AT 3,10;"U           U"; AT 4,10;"UUUUUUUUUUUUU"
9056 PRINT  AT 2,12;BRIGHT 1;FLASH 1;"P A N I C"
9060 PRINT  AT 7,0;PAPER 5;INK 0;"TECLAS DE CONTROL:"; AT 9,5;"IZQUIERDA ---------- 'O'"; AT 11,5;"DERECHA ------------ 'P'"; AT 13,5;"ARRIBA ------------- 'Q'"; AT 15,5;"ABAJO -------------- 'A'"; AT 17,5;"ABRIR AGUJERO ------ 'M'"; AT 19,5;"CERRAR AGUJERO ----- 'Z'"
9070 PRINT #1;"PULSA 'S' PARA COMENZAR A JUGAR.";
9080 IF INKEY$ <>"S" THEN GO TO 9080
9090 GO TO 10
9099 :
9100 REM GRABACION
9101 :
9110 SAVE "PANIC"LINE 9000
9120 SAVE "PANIC CODE 1"CODE 59656,168:SAVE "PANIC CODE 2"CODE USR "A",168
9130 STOP 
9200 REM FINAL
9210 OVER 0:PAPER 0:INK 7:BORDER 0:BRIGHT 1:CLS 
9220 FOR N=0 TO 3:PRINT  AT N,0;PAPER 7;INK 1;"qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq";:NEXT N:FOR N=13 TO 21:PRINT  AT N,0;PAPER 7;INK 1;"qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq";:NEXT N
9230 PRINT  AT 10,30;PAPER 7;INK 1;"qq";PAPER 7;INK 2; AT 11,31;"q"; AT 12,31;"q"
9240 LET A$="AAAAAAAAAAA           ":LET B$="BBBBBBBBBBB           ":LET C$="EEEEEEEEEEE           ":LET D$="FFFFFFFFFFF           ":LET E$="ababab                   ":LET F$="cdcdcd                   ":LET G$="efefef                   ":LET H$="ghghgh                   ":LET I$="mnmnmn":LET J$="opopop"
9250 PRINT INK 5; AT 11,25;G$( TO 6); AT 12,25;H$( TO 6):FOR N=1 TO 5:BEEP .1,N:PRINT  AT 11,N;" C"; AT 12,N;" D":NEXT N:PAUSE 20:PRINT  AT 11,6;"ST"; AT 12,6;"O ":BEEP .1,50:PRINT  AT 11,6;"MN"; AT 12,6;"OP":BEEP .1,0
9255 FOR N=13 TO 20:PRINT  AT N,7;"      ":BEEP .05,20:NEXT N:PRINT  AT 11,6;"C "; AT 12,6;"D "
9260 FOR N=7 TO 24 STEP 2:PRINT  AT 11,31-N;INK 5;E$( TO N); AT 12,31-N;F$( TO N):BEEP .1,N:PRINT INK 5; AT 11,30-N;G$( TO N); AT 12,30-N;H$( TO N):BEEP .1,40-N:NEXT N
9270 FOR N=12 TO 19:PRINT INK 5; AT N,7;I$; AT N+1,7;J$; AT N-1,7;"      ":BEEP .01,N+40:NEXT N:BEEP .7,-40:PRINT  AT 19,7;INK 3;I$; AT 20,7;J$
9275 PAUSE 20:FOR N=7 TO 12:PLOT OVER 1;PAPER 8;INK 8;128,0:DRAW OVER 1;PAPER 8;INK 8;N*8+4-128,150:PLOT OVER 1;PAPER 8;INK 8;128,0:DRAW OVER 1;PAPER 8;INK 8;N*8+4-128,150:BEEP .01,50:PRINT  AT 3,N;" "; AT 4,N;PAPER 7;INK 1;"q":NEXT N
9280 FOR N=5 TO 20:PRINT PAPER 7;INK 1; AT N,7;"qqqqqq";PAPER 0; AT N-1,7;"      ":BEEP .05,60-N:NEXT N:BEEP 1,0
9290 FOR N=19 TO 13 STEP -1:PRINT PAPER 7;INK 1; AT N,7;"qqqqqq":NEXT N
9300 FOR N=1 TO 22 STEP 2:PRINT  AT 11,31-N;A$( TO N); AT 12,31-N;B$( TO N):BEEP .05,30:PRINT  AT 11,31-N;C$( TO N); AT 12,31-N;D$( TO N):BEEP .05,40:PRINT  AT 11,30-N;A$( TO N); AT 12,30-N;B$( TO N):BEEP .05,50:NEXT N
9310 FOR N=1 TO 10:PRINT  AT 10,9;A$( TO 11); AT 11,9;B$( TO 11); AT 12,9;"           ":BEEP .1,60:PRINT  AT 10,9;"           "; AT 11,9;A$( TO 11); AT 12,9;B$( TO 11):BEEP .1,65:NEXT N
9320 PAUSE 50:CLS :PRINT  AT 5,10;"FELICIDADES"; AT 10,5;"HAS COMPLETADO EL JUEGO"; AT 12,2;"Y HAS CONSEGUIDO ";SCORE;" PUNTOS"; AT 14,2;"EL ";INT ((SCORE*100/455700)+.5);"% DE LA PUNTUACION MAXIMA":FOR N=1 TO 10:FOR K=60 TO -30 STEP -5:BEEP .003,K:NEXT K:NEXT N
9330 BRIGHT 0:LET HIGH=(SCORE AND HIGH<SCORE)+(HIGH AND SCORE<HIGH):GO TO 9050
9900 REM SUBRUTINA LASER
9910 FOR N=175-D*8-4 TO 175-C*8-4 STEP 16:FOR K=A*8-128 TO B*8-128 STEP 8
9920 BEEP .001,60:PLOT 128,0:DRAW INK 4;OVER 1;K,N:PLOT OVER 1;128,0:DRAW OVER 1;K,N:NEXT K
9930 IF N<175-C*8-4 THEN FOR K=B*8-128 TO A*8-128 STEP -8:BEEP .001,50:PLOT 128,0:DRAW INK 2;OVER 1;K,N+8:PLOT INVERSE 1;128,0:DRAW OVER 1;K,N+8:NEXT K
9940 NEXT N:RETURN